home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Libris Britannia 4
/
science library(b).zip
/
science library(b)
/
ENGINEER
/
CAM
/
1172.ZIP
/
LATHEXMP.APT
< prev
next >
Wrap
Text File
|
1990-09-01
|
2KB
|
69 lines
PARTNO PERSONAL APT SAMPLE LATHE PROGRAM
MACHIN/LATHE1,1
PRINT/ON
L1=LINE/(POINT/5,1),ATANGL,0
L2=LINE/(POINT/5.1,1),ATANGL,60
L3=LINE/XCOORD,3
L4=LINE/XCOORD,5.1
LTLCHG=MACRO/IFACE,OFSET,GLX,GLY,DIR=CLW,SPD,FED,TLR=0
GOHOME
TURRET/IFACE,OFSET,GLX,GLY,DIR
SPINDL/SPD,SFM,INCR,.1
FEDRAT/FED,IPR
CUTTER/(TLR*2)
TERMAC
THRDOD=MACRO/MAJLN,THPI,DCLR=.05,BEGLN,ENDLN,NPASS=4
PRINT/OFF
DEPTH= COSF(30)/THPI
DINCR= DEPTH/NPASS
CLRLN=LINE/PARLEL,MAJLN,YLARGE,DCLR
BEGPT=POINT/INTOF,CLRLN,BEGLN
THDIR=VECTOR/(POINT/INTOF,BEGLN,MAJLN),(POINT/INTOF,ENDLN,MAJLN)
PITCH/TPI,THPI
DP= 0
REDEF/ON
TLON
$$BEGIN LOOP
I= 0
BEGIN: DP= DP+DINCR
IF (DEPTH - DP) WIPE, AGAIN, AGAIN
AGAIN: RAPID,GOTO/BEGPT
INDIRV/0,-1,0
GOFWD/BEGLN,ON,(LX=LINE/PARLEL,MAJLN,YSMALL,DP)
THREAD/ON
INDIRV/THDIR
GOFWD/LX
INDIRV/0,1,0
GOFWD/ENDLN,ON,CLRLN
IF (I) BEGIN, BEGIN, FINIS
WIPE: DP= DEPTH
I= 1
JUMPTO/AGAIN
FINIS: REDEF/OFF
PRINT/ON
TERMAC
FROM/12,8,0
CALL/LTLCHG,IFACE=1,OFSET=1,GLX=-4,GLY=-5,SPD=350,FED=.012,TLR=.094
RAPID,GO/(LINE/YCOORD,1.25),(PL1=PLANE/0,0,1,0),L4
ID1: GO/PAST,(LINE/XCOORD,2.75)
RAPID,GODLTA/.05,.05,0
RAPID,GO/PAST,L4
RETURN
RAPID,GO/TO,L1
GOSUB/ID1
CUTTER/0
RAPID,GOTO/5,5,0
GOTO/5,0,0
GOTO/5,2,0
GOTO/4,2,0
GOFWD/(CX=CIRCLE/4,5,3),ON,(LINE/0,5,1,5)
GOBACK/CX,ON,(LINE/4,0,4,1)
CALL/LTLCHG,IFACE=2,OFSET=2,GLX=-3.5,GLY=-4.9,SPD=75,FED=.1
SPINDL/350,RPM
CALL/THRDOD,MAJLN=L1,BEGLN=L2,ENDLN=L3,NPASS=4,THPI=8
CALL/LTLCHG,IFACE=0,OFSET=0,GLX=0,GLY=0,DIR=CCLW,SPD=300,FED=.1
REWIND
PRINT/3,ALL
END
FINI